c9baba9212
(My OCD kicked in today...) Remove repeated package names, capitalize first word, remove trailing periods and move overlong descriptions to longDescription. I also simplified some descriptions as well, when they were particularly long or technical, often based on Arch Linux' package descriptions. I've tried to stay away from generated expressions (and I think I succeeded). Some specifics worth mentioning: * cron, has "Vixie Cron" in its description. The "Vixie" part is not mentioned anywhere else. I kept it in a parenthesis at the end of the description. * ctags description started with "Exuberant Ctags ...", and the "exuberant" part is not mentioned elsewhere. Kept it in a parenthesis at the end of description. * nix has the description "The Nix Deployment System". Since that doesn't really say much what it is/does (especially after removing the package name!), I changed that to "Powerful package manager that makes package management reliable and reproducible" (borrowed from nixos.org). * Tons of "GNU Foo, Foo is a [the important bits]" descriptions is changed to just [the important bits]. If the package name doesn't contain GNU I don't think it's needed to say it in the description either.
88 lines
2.9 KiB
Nix
88 lines
2.9 KiB
Nix
{ stdenv, fetchurl, noSysDirs, zlib
|
|
, cross ? null, gold ? true, bison ? null
|
|
}:
|
|
|
|
let basename = "binutils-2.23.1"; in
|
|
|
|
with { inherit (stdenv.lib) optional optionals optionalString; };
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = basename + optionalString (cross != null) "-${cross.config}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnu/binutils/${basename}.tar.bz2";
|
|
sha256 = "06bs5v5ndb4g5qx96d52lc818gkbskd1m0sz57314v887sqfbcia";
|
|
};
|
|
|
|
patches = [
|
|
# Turn on --enable-new-dtags by default to make the linker set
|
|
# RUNPATH instead of RPATH on binaries. This is important because
|
|
# RUNPATH can be overriden using LD_LIBRARY_PATH at runtime.
|
|
./new-dtags.patch
|
|
|
|
# Since binutils 2.22, DT_NEEDED flags aren't copied for dynamic outputs.
|
|
# That requires upstream changes for things to work. So we can patch it to
|
|
# get the old behaviour by now.
|
|
./dtneeded.patch
|
|
|
|
# Make binutils output deterministic by default.
|
|
./deterministic.patch
|
|
|
|
# Always add PaX flags section to ELF files.
|
|
# This is needed, for instance, so that running "ldd" on a binary that is
|
|
# PaX-marked to disable mprotect doesn't fail with permission denied.
|
|
./pt-pax-flags-20121023.patch
|
|
];
|
|
|
|
buildInputs =
|
|
[ zlib ]
|
|
++ optional gold bison;
|
|
|
|
inherit noSysDirs;
|
|
|
|
preConfigure = ''
|
|
# Clear the default library search path.
|
|
if test "$noSysDirs" = "1"; then
|
|
echo 'NATIVE_LIB_DIRS=' >> ld/configure.tgt
|
|
fi
|
|
|
|
# Use symlinks instead of hard links to save space ("strip" in the
|
|
# fixup phase strips each hard link separately).
|
|
for i in binutils/Makefile.in gas/Makefile.in ld/Makefile.in gold/Makefile.in; do
|
|
sed -i "$i" -e 's|ln |ln -s |'
|
|
done
|
|
'';
|
|
|
|
# As binutils takes part in the stdenv building, we don't want references
|
|
# to the bootstrap-tools libgcc (as uses to happen on arm/mips)
|
|
NIX_CFLAGS_COMPILE = "-static-libgcc";
|
|
|
|
configureFlags =
|
|
[ "--enable-shared" "--enable-deterministic-archives" ]
|
|
++ optional (stdenv.system == "mips64el-linux") "--enable-fix-loongson2f-nop"
|
|
++ optional (cross != null) "--target=${cross.config}"
|
|
++ optionals gold [ "--enable-gold" "--enable-plugins" ]
|
|
++ optional (stdenv.system == "i686-linux") "--enable-targets=x86_64-linux-gnu";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "Tools for manipulating binaries (linker, assembler, etc.)";
|
|
|
|
longDescription = ''
|
|
The GNU Binutils are a collection of binary tools. The main
|
|
ones are `ld' (the GNU linker) and `as' (the GNU assembler).
|
|
They also include the BFD (Binary File Descriptor) library,
|
|
`gprof', `nm', `strip', etc.
|
|
'';
|
|
|
|
homepage = http://www.gnu.org/software/binutils/;
|
|
|
|
license = stdenv.lib.licenses.gpl3Plus;
|
|
|
|
/* Give binutils a lower priority than gcc-wrapper to prevent a
|
|
collision due to the ld/as wrappers/symlinks in the latter. */
|
|
priority = "10";
|
|
};
|
|
}
|