c9baba9212
(My OCD kicked in today...) Remove repeated package names, capitalize first word, remove trailing periods and move overlong descriptions to longDescription. I also simplified some descriptions as well, when they were particularly long or technical, often based on Arch Linux' package descriptions. I've tried to stay away from generated expressions (and I think I succeeded). Some specifics worth mentioning: * cron, has "Vixie Cron" in its description. The "Vixie" part is not mentioned anywhere else. I kept it in a parenthesis at the end of the description. * ctags description started with "Exuberant Ctags ...", and the "exuberant" part is not mentioned elsewhere. Kept it in a parenthesis at the end of description. * nix has the description "The Nix Deployment System". Since that doesn't really say much what it is/does (especially after removing the package name!), I changed that to "Powerful package manager that makes package management reliable and reproducible" (borrowed from nixos.org). * Tons of "GNU Foo, Foo is a [the important bits]" descriptions is changed to just [the important bits]. If the package name doesn't contain GNU I don't think it's needed to say it in the description either.
108 lines
3.5 KiB
Nix
108 lines
3.5 KiB
Nix
{ lib, stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
|
||
, libjpeg, zlib, dbus, dbus_glib, bzip2, xlibs
|
||
, freetype, fontconfig, file, alsaLib, nspr, nss, libnotify
|
||
, yasm, mesa, sqlite, unzip, makeWrapper, pysqlite
|
||
, hunspell, libevent, libstartup_notification, libvpx
|
||
, cairo, gstreamer, gst_plugins_base, icu
|
||
, debugBuild ? false
|
||
, # If you want the resulting program to call itself "Firefox" instead
|
||
# of "Shiretoko" or whatever, enable this option. However, those
|
||
# binaries may not be distributed without permission from the
|
||
# Mozilla Foundation, see
|
||
# http://www.mozilla.org/foundation/trademarks/.
|
||
enableOfficialBranding ? false
|
||
}:
|
||
|
||
assert stdenv.gcc ? libc && stdenv.gcc.libc != null;
|
||
|
||
let version = "31.0"; in
|
||
|
||
stdenv.mkDerivation rec {
|
||
name = "firefox-${version}";
|
||
|
||
src = fetchurl {
|
||
url = "http://ftp.mozilla.org/pub/mozilla.org/firefox/releases/${version}/source/firefox-${version}.source.tar.bz2";
|
||
sha1 = "a6c3e25ee3aeb7da42db2aaeb50a385d63532beb";
|
||
};
|
||
|
||
buildInputs =
|
||
[ pkgconfig gtk perl zip libIDL libjpeg zlib bzip2
|
||
python dbus dbus_glib pango freetype fontconfig xlibs.libXi
|
||
xlibs.libX11 xlibs.libXrender xlibs.libXft xlibs.libXt file
|
||
alsaLib nspr nss libnotify xlibs.pixman yasm mesa
|
||
xlibs.libXScrnSaver xlibs.scrnsaverproto pysqlite
|
||
xlibs.libXext xlibs.xextproto sqlite unzip makeWrapper
|
||
hunspell libevent libstartup_notification libvpx cairo
|
||
gstreamer gst_plugins_base icu
|
||
];
|
||
|
||
configureFlags =
|
||
[ "--enable-application=browser"
|
||
"--disable-javaxpcom"
|
||
"--with-system-jpeg"
|
||
"--with-system-zlib"
|
||
"--with-system-bz2"
|
||
"--with-system-nspr"
|
||
"--with-system-nss"
|
||
"--with-system-libevent"
|
||
"--with-system-libvpx"
|
||
# "--with-system-png" # needs APNG support
|
||
# "--with-system-icu" # causes ‘ar: invalid option -- 'L'’ in Firefox 28.0
|
||
"--enable-system-ffi"
|
||
"--enable-system-hunspell"
|
||
"--enable-system-pixman"
|
||
"--enable-system-sqlite"
|
||
"--enable-system-cairo"
|
||
"--enable-gstreamer"
|
||
"--enable-startup-notification"
|
||
# "--enable-content-sandbox" # available since 26.0, but not much info available
|
||
# "--enable-content-sandbox-reporter" # keeping disabled for now
|
||
"--disable-crashreporter"
|
||
"--disable-tests"
|
||
"--disable-necko-wifi" # maybe we want to enable this at some point
|
||
"--disable-installer"
|
||
"--disable-updater"
|
||
"--disable-pulseaudio"
|
||
]
|
||
++ (if debugBuild then [ "--enable-debug" "--enable-profiling"]
|
||
else [ "--disable-debug" "--enable-release"
|
||
"--enable-optimize" "--enable-strip" ])
|
||
++ lib.optional enableOfficialBranding "--enable-official-branding";
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
preConfigure =
|
||
''
|
||
mkdir ../objdir
|
||
cd ../objdir
|
||
configureScript=../mozilla-release/configure
|
||
'';
|
||
|
||
preInstall =
|
||
''
|
||
# The following is needed for startup cache creation on grsecurity kernels.
|
||
paxmark m ../objdir/dist/bin/xpcshell
|
||
'';
|
||
|
||
postInstall =
|
||
''
|
||
# For grsecurity kernels
|
||
paxmark m $out/lib/*/{plugin-container,xulrunner}
|
||
|
||
# Remove SDK cruft. FIXME: move to a separate output?
|
||
rm -rf $out/share/idl $out/include $out/lib/firefox-devel-*
|
||
'';
|
||
|
||
meta = {
|
||
description = "Web browser";
|
||
homepage = http://www.mozilla.com/en-US/firefox/;
|
||
maintainers = with lib.maintainers; [ eelco wizeman ];
|
||
platforms = lib.platforms.linux;
|
||
};
|
||
|
||
passthru = {
|
||
inherit gtk nspr version;
|
||
isFirefox3Like = true;
|
||
};
|
||
}
|