31039fead2
factor out the commonality. * Removed the "strip -S", which should not be needed anymore. * The enableOfficialBranding flag didn't do anything anymore. svn path=/nixpkgs/trunk/; revision=16166
131 lines
3.6 KiB
Nix
131 lines
3.6 KiB
Nix
{ stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
|
|
, libjpeg, libpng, zlib, cairo, dbus, dbus_glib, bzip2, xlibs
|
|
, freetype, fontconfig, file
|
|
|
|
, # If you want the resulting program to call itself "Firefox" instead
|
|
# of "Deer Park", enable this option. However, those binaries may
|
|
# not be distributed without permission from the Mozilla Foundation,
|
|
# see http://www.mozilla.org/foundation/trademarks/.
|
|
enableOfficialBranding ? false
|
|
}:
|
|
|
|
rec {
|
|
|
|
firefoxVersion = "3.0.11";
|
|
|
|
xulVersion = "1.9.0.11"; # this attribute is used by other packages
|
|
|
|
|
|
src = fetchurl {
|
|
url = "http://releases.mozilla.org/pub/mozilla.org/firefox/releases/${firefoxVersion}/source/firefox-${firefoxVersion}-source.tar.bz2";
|
|
sha1 = "ca792dcdb67af40c91a4fcece25d6adfb6fef2c3";
|
|
};
|
|
|
|
|
|
commonConfigureFlags =
|
|
[ "--enable-optimize"
|
|
"--disable-debug"
|
|
"--enable-strip"
|
|
"--with-system-jpeg"
|
|
"--with-system-zlib"
|
|
"--with-system-bz2"
|
|
# "--with-system-png" # <-- "--with-system-png won't work because the system's libpng doesn't have APNG support"
|
|
"--enable-system-cairo"
|
|
#"--enable-system-sqlite" # <-- this seems to be discouraged
|
|
"--disable-crashreporter"
|
|
];
|
|
|
|
|
|
xulrunner = stdenv.mkDerivation {
|
|
name = "xulrunner-${xulVersion}";
|
|
|
|
inherit src;
|
|
|
|
buildInputs =
|
|
[ pkgconfig gtk perl zip libIDL libjpeg libpng zlib cairo bzip2
|
|
python dbus dbus_glib pango freetype fontconfig xlibs.libXi
|
|
xlibs.libX11 xlibs.libXrender xlibs.libXft xlibs.libXt file
|
|
];
|
|
|
|
configureFlags =
|
|
[ "--enable-application=xulrunner"
|
|
"--disable-javaxpcom"
|
|
] ++ commonConfigureFlags;
|
|
|
|
installFlags = "SKIP_GRE_REGISTRATION=1";
|
|
|
|
postInstall = ''
|
|
export dontPatchELF=1
|
|
|
|
# Fix some references to /bin paths in the Xulrunner shell script.
|
|
substituteInPlace $out/bin/xulrunner \
|
|
--replace /bin/pwd "$(type -tP pwd)" \
|
|
--replace /bin/ls "$(type -tP ls)"
|
|
|
|
# Fix run-mozilla.sh search
|
|
libDir=$(cd $out/lib && ls -d xulrunner-[0-9]*)
|
|
echo libDir: $libDir
|
|
test -n "$libDir"
|
|
cd $out/bin
|
|
mv xulrunner ../lib/$libDir/
|
|
|
|
for i in $out/lib/$libDir/*; do
|
|
file $i;
|
|
if file $i | grep executable &>/dev/null; then
|
|
ln -s $i $out/bin
|
|
fi;
|
|
done;
|
|
rm $out/bin/run-mozilla.sh || true
|
|
''; # */
|
|
|
|
meta = {
|
|
description = "Mozilla Firefox XUL runner";
|
|
homepage = http://www.mozilla.com/en-US/firefox/;
|
|
};
|
|
|
|
passthru = { inherit gtk; version = xulVersion; };
|
|
};
|
|
|
|
|
|
firefox = stdenv.mkDerivation rec {
|
|
name = "firefox-3.0.11";
|
|
|
|
inherit src;
|
|
|
|
buildInputs =
|
|
[ pkgconfig gtk perl zip libIDL libjpeg zlib cairo bzip2 python
|
|
dbus dbus_glib pango freetype fontconfig
|
|
];
|
|
|
|
propagatedBuildInputs = [xulrunner];
|
|
|
|
configureFlags =
|
|
[ "--enable-application=browser"
|
|
"--with-libxul-sdk=${xulrunner}/lib/xulrunner-devel-${xulrunner.version}"
|
|
]
|
|
++ commonConfigureFlags
|
|
++ stdenv.lib.optional enableOfficialBranding "--enable-official-branding";
|
|
|
|
postInstall = ''
|
|
libDir=$(cd $out/lib && ls -d firefox-[0-9]*)
|
|
test -n "$libDir"
|
|
|
|
ln -s ${xulrunner}/lib/xulrunner-${xulrunner.version} $out/lib/$libDir/xulrunner
|
|
|
|
# Register extensions etc. !!! is this needed anymore?
|
|
echo "running firefox -register..."
|
|
$out/bin/firefox -register
|
|
''; # */
|
|
|
|
meta = {
|
|
description = "Mozilla Firefox - the browser, reloaded";
|
|
homepage = http://www.mozilla.com/en-US/firefox/;
|
|
};
|
|
|
|
passthru = {
|
|
inherit gtk;
|
|
isFirefox3Like = true;
|
|
};
|
|
};
|
|
}
|