2aba922d30
My idea is to provide special stdenv expressions that will contain in the path
additional cross compilers. As most expressions for programs accept a stdenv parameter,
we could substitute this parameter with the special stdenv, which will have a
generic builder that attempts the usual "--target=..." and can additionally
have an env variable like "cross" with the target architecture set.
So, finally we could have additional expressions like this:
bashRealArm = makeOverridable (import ../shells/bash) {
inherit fetchurl bison;
stdenv = stdenvCross "armv5tel-unknown-linux-gnueabi";
};
Meanwhile it does not work - I still cannot get the cross-gcc to build.
I think it does not fill the previous expressions with a lot of noise, so I
think it may be a good path to follow.
I only touched some files of the current stdenv: gcc-4.3, kernel headers
2.6.28, glibc 2.9, ...
I tried to use the gcc-cross-wrapper, that may be very outdated. Maybe I will
update it, or update the gcc-wrapper expression to make it fit the cross tools,
but meanwhile I even cannot build gcc, so I have not tested the wrapper.
This new idea on cross compiling is not similar to that of the
nixpkgs/branches/cross-compilation, which mostly added bare new expressions for
anything to be cross compiled, if I understood it correctly.
I cared not to break anything of the usual stdenv in all this work.
svn path=/nixpkgs/branches/stdenv-updates/; revision=18343
98 lines
3 KiB
Nix
98 lines
3 KiB
Nix
{ stdenv, fetchurl, kernelHeaders
|
|
, installLocales ? true
|
|
, profilingLibraries ? false
|
|
, cross ? null
|
|
, binutilsCross ? null
|
|
, gccCross ? null
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "glibc-2.9" +
|
|
stdenv.lib.optionalString (cross != null) "-${cross}";
|
|
|
|
builder = ./builder.sh;
|
|
|
|
src = fetchurl {
|
|
url = http://ftp.gnu.org/gnu/glibc/glibc-2.9.tar.bz2;
|
|
sha256 = "0v53m7flx6qcx7cvrvvw6a4dx4x3y6k8nvpc4wfv5xaaqy2am2q9";
|
|
};
|
|
|
|
srcPorts = fetchurl {
|
|
url = http://ftp.gnu.org/gnu/glibc/glibc-ports-2.9.tar.bz2;
|
|
sha256 = "0r2sn527wxqifi63di7ns9wbjh1cainxn978w178khhy7yw9fk42";
|
|
};
|
|
|
|
inherit kernelHeaders installLocales;
|
|
|
|
inherit (stdenv) is64bit;
|
|
|
|
patches = [
|
|
/* Fix for NIXPKGS-79: when doing host name lookups, when
|
|
nsswitch.conf contains a line like
|
|
|
|
hosts: files mdns4_minimal [NOTFOUND=return] dns mdns4
|
|
|
|
don't return an error when mdns4_minimal can't be found. This
|
|
is a bug in Glibc: when a service can't be found, NSS should
|
|
continue to the next service unless "UNAVAIL=return" is set.
|
|
("NOTFOUND=return" refers to the service returning a NOTFOUND
|
|
error, not the service itself not being found.) The reason is
|
|
that the "status" variable (while initialised to UNAVAIL) is
|
|
outside of the loop that iterates over the services, the
|
|
"files" service sets status to NOTFOUND. So when the call to
|
|
find "mdns4_minimal" fails, "status" will still be NOTFOUND,
|
|
and it will return instead of continuing to "dns". Thus, the
|
|
line
|
|
|
|
hosts: mdns4_minimal [NOTFOUND=return] dns mdns4
|
|
|
|
does work because "status" will contain UNAVAIL after the
|
|
failure to find mdns4_minimal. */
|
|
./nss-skip-unavail.patch
|
|
|
|
/* Make it possible to override the locale-archive in NixOS. */
|
|
./locale-override.patch
|
|
|
|
/* Have rpcgen(1) look for cpp(1) in $PATH. */
|
|
./rpcgen-path.patch
|
|
|
|
/* Support GNU Binutils 2.20 and above. */
|
|
./binutils-2.20.patch
|
|
];
|
|
|
|
configureFlags = [
|
|
"--enable-add-ons"
|
|
"--with-headers=${kernelHeaders}/include"
|
|
(if profilingLibraries then "--enable-profile" else "--disable-profile")
|
|
] ++ stdenv.lib.optionals (cross != null) [
|
|
"--target=${cross}"
|
|
] ++ (if (stdenv.system == "armv5tel-linux") then [
|
|
"--host=arm-linux-gnueabi"
|
|
"--build=arm-linux-gnueabi"
|
|
"--without-fp"
|
|
] else []);
|
|
|
|
buildInputs = stdenv.lib.optionals (cross != null) [ binutilsCross gccCross ];
|
|
|
|
preInstall = ''
|
|
ensureDir $out/lib
|
|
ln -s ${stdenv.gcc.gcc}/lib/libgcc_s.so.1 $out/lib/libgcc_s.so.1
|
|
'';
|
|
|
|
postInstall = ''
|
|
rm $out/lib/libgcc_s.so.1
|
|
'';
|
|
|
|
# Workaround for this bug:
|
|
# http://sourceware.org/bugzilla/show_bug.cgi?id=411
|
|
# I.e. when gcc is compiled with --with-arch=i686, then the
|
|
# preprocessor symbol `__i686' will be defined to `1'. This causes
|
|
# the symbol __i686.get_pc_thunk.dx to be mangled.
|
|
NIX_CFLAGS_COMPILE = "-U__i686";
|
|
|
|
meta = {
|
|
homepage = http://www.gnu.org/software/libc/;
|
|
description = "The GNU C Library";
|
|
};
|
|
}
|