176 lines
8.0 KiB
Nix
176 lines
8.0 KiB
Nix
{ stdenv, requireFile, perl, unzip, glibc, zlib, bzip2, gdk-pixbuf, xorg, glib, fontconfig, freetype, cairo, pango, gtk3, gtk2, ffmpeg_3, libGL, atk, alsaLib, libav_0_8, setJavaClassPath }:
|
|
|
|
let
|
|
common = javaVersion:
|
|
let
|
|
graalvmXXX-ee = stdenv.mkDerivation rec {
|
|
pname = "graalvm${javaVersion}-ee";
|
|
version = "20.0.0";
|
|
srcs = [
|
|
(requireFile {
|
|
name = "graalvm-ee-java${javaVersion}-linux-amd64-${version}.tar.gz";
|
|
sha256 = { "8" = "2df9b31b96f7a24b6a2fe3ecea0b5e819d5d058fde6320016dba1787ce59e99e";
|
|
"11" = "b704fd27b5993584a1ad659b41f42ff0ae8893c066b64a6f6a1719fbee382536";
|
|
}.${javaVersion};
|
|
url = "https://www.oracle.com/technetwork/graalvm/downloads/index.html";
|
|
})
|
|
(requireFile {
|
|
name = "native-image-installable-svm-svmee-java${javaVersion}-linux-amd64-${version}.jar";
|
|
sha256 = { "8" = "a9f3f86d880d133bd24ad3b1d95129a96e80ea1d8fbc865d09e9410b921e6897";
|
|
"11" = "57086123a95f1e9d4e67b92f830bad9325431908c69a40ef10f28ed586d8bd35";
|
|
}.${javaVersion};
|
|
url = "https://www.oracle.com/technetwork/graalvm/downloads/index.html";
|
|
})
|
|
(requireFile {
|
|
name = "ruby-installable-svm-svmee-java${javaVersion}-linux-amd64-${version}.jar";
|
|
sha256 = { "8" = "28b2910736f41070c84b97f1b1a3c5fa43ebdcd926ec92c8f145550b5b975b3c";
|
|
"11" = "27ff1befa67fe5cc9eb0216b6b1105876f44d13eff6137f36f29f13377ea687b";
|
|
}.${javaVersion};
|
|
url = "https://www.oracle.com/technetwork/graalvm/downloads/index.html";
|
|
})
|
|
(requireFile {
|
|
name = "python-installable-svm-svmee-java${javaVersion}-linux-amd64-${version}.jar";
|
|
sha256 = { "8" = "9c83bcd71e316805c2914c9002ce348ae44829606adc2375d9188b1eaaaf82f9";
|
|
"11" = "5ca51478bcb5ea5bd9be35856dd7fb2ef03b888cd1b7284a8c15531979025fb4";
|
|
}.${javaVersion};
|
|
url = "https://www.oracle.com/technetwork/graalvm/downloads/index.html";
|
|
})
|
|
(requireFile {
|
|
name = "wasm-installable-svm-svmee-java${javaVersion}-linux-amd64-${version}.jar";
|
|
sha256 = { "8" = "e8bd14d3f9bf652104e4346e0899a0351afaecae030a9c0ce0f91b1f93d9e660";
|
|
"11" = "d24eeb84625bb7a5e330b897fd6dde7fc579a687997b64625199c33fa83c40b4";
|
|
}.${javaVersion};
|
|
url = "https://www.oracle.com/technetwork/graalvm/downloads/index.html";
|
|
})
|
|
];
|
|
nativeBuildInputs = [ unzip perl ];
|
|
unpackPhase = ''
|
|
unpack_jar() {
|
|
jar=$1
|
|
unzip $jar -d $out
|
|
perl -ne 'use File::Path qw(make_path);
|
|
use File::Basename qw(dirname);
|
|
if (/^(.+) = (.+)$/) {
|
|
make_path dirname("$ENV{out}/$1");
|
|
system "ln -s $2 $ENV{out}/$1";
|
|
}' $out/META-INF/symlinks
|
|
perl -ne 'if (/^(.+) = ([r-])([w-])([x-])([r-])([w-])([x-])([r-])([w-])([x-])$/) {
|
|
my $mode = ($2 eq 'r' ? 0400 : 0) + ($3 eq 'w' ? 0200 : 0) + ($4 eq 'x' ? 0100 : 0) +
|
|
($5 eq 'r' ? 0040 : 0) + ($6 eq 'w' ? 0020 : 0) + ($7 eq 'x' ? 0010 : 0) +
|
|
($8 eq 'r' ? 0004 : 0) + ($9 eq 'w' ? 0002 : 0) + ($10 eq 'x' ? 0001 : 0);
|
|
chmod $mode, "$ENV{out}/$1";
|
|
}' $out/META-INF/permissions
|
|
rm -rf $out/META-INF
|
|
}
|
|
|
|
mkdir -p $out
|
|
arr=($srcs)
|
|
tar xf ''${arr[0]} -C $out --strip-components=1
|
|
unpack_jar ''${arr[1]}
|
|
unpack_jar ''${arr[2]}
|
|
unpack_jar ''${arr[3]}
|
|
unpack_jar ''${arr[4]}
|
|
'';
|
|
|
|
installPhase = {
|
|
"8" = ''
|
|
# BUG workaround http://mail.openjdk.java.net/pipermail/graal-dev/2017-December/005141.html
|
|
substituteInPlace $out/jre/lib/security/java.security \
|
|
--replace file:/dev/random file:/dev/./urandom \
|
|
--replace NativePRNGBlocking SHA1PRNG
|
|
|
|
# provide libraries needed for static compilation
|
|
for f in ${glibc}/lib/* ${glibc.static}/lib/* ${zlib.static}/lib/*; do
|
|
ln -s $f $out/jre/lib/svm/clibraries/linux-amd64/$(basename $f)
|
|
done
|
|
|
|
# allow using external truffle-api.jar and languages not included in the distrubution
|
|
rm $out/jre/lib/jvmci/parentClassLoader.classpath
|
|
'';
|
|
"11" = ''
|
|
# BUG workaround http://mail.openjdk.java.net/pipermail/graal-dev/2017-December/005141.html
|
|
substituteInPlace $out/conf/security/java.security \
|
|
--replace file:/dev/random file:/dev/./urandom \
|
|
--replace NativePRNGBlocking SHA1PRNG
|
|
|
|
# provide libraries needed for static compilation
|
|
for f in ${glibc}/lib/* ${glibc.static}/lib/* ${zlib.static}/lib/*; do
|
|
ln -s $f $out/lib/svm/clibraries/linux-amd64/$(basename $f)
|
|
done
|
|
'';
|
|
}.${javaVersion};
|
|
|
|
dontStrip = true;
|
|
|
|
# copy-paste openjdk's preFixup
|
|
preFixup = ''
|
|
# Set JAVA_HOME automatically.
|
|
mkdir -p $out/nix-support
|
|
cat <<EOF > $out/nix-support/setup-hook
|
|
if [ -z "\''${JAVA_HOME-}" ]; then export JAVA_HOME=$out; fi
|
|
EOF
|
|
'';
|
|
|
|
postFixup = ''
|
|
rpath="${ { "8" = "$out/jre/lib/amd64/jli:$out/jre/lib/amd64/server:$out/jre/lib/amd64";
|
|
"11" = "$out/lib/jli:$out/lib/server:$out/lib";
|
|
}.${javaVersion}
|
|
}:${
|
|
stdenv.lib.strings.makeLibraryPath [ glibc xorg.libXxf86vm xorg.libX11 xorg.libXext xorg.libXtst xorg.libXi xorg.libXrender
|
|
glib zlib bzip2 alsaLib fontconfig freetype pango gtk3 gtk2 cairo gdk-pixbuf atk ffmpeg_3 libGL ]}"
|
|
|
|
for f in $(find $out -type f -perm -0100); do
|
|
patchelf --interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" "$f" || true
|
|
patchelf --set-rpath "$rpath" "$f" || true
|
|
done
|
|
|
|
for f in $(find $out -type f -perm -0100); do
|
|
if ldd "$f" | fgrep 'not found'; then echo "in file $f"; fi
|
|
done
|
|
'';
|
|
|
|
propagatedBuildInputs = [ setJavaClassPath zlib ]; # $out/bin/native-image needs zlib to build native executables
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
echo ${stdenv.lib.escapeShellArg ''
|
|
public class HelloWorld {
|
|
public static void main(String[] args) {
|
|
System.out.println("Hello World");
|
|
}
|
|
}
|
|
''} > HelloWorld.java
|
|
$out/bin/javac HelloWorld.java
|
|
|
|
# run on JVM with Graal Compiler
|
|
$out/bin/java -XX:+UnlockExperimentalVMOptions -XX:+EnableJVMCI -XX:+UseJVMCICompiler HelloWorld
|
|
$out/bin/java -XX:+UnlockExperimentalVMOptions -XX:+EnableJVMCI -XX:+UseJVMCICompiler HelloWorld | fgrep 'Hello World'
|
|
|
|
# Ahead-Of-Time compilation
|
|
$out/bin/native-image --no-server HelloWorld
|
|
./helloworld
|
|
./helloworld | fgrep 'Hello World'
|
|
|
|
# Ahead-Of-Time compilation with --static
|
|
$out/bin/native-image --no-server --static HelloWorld
|
|
./helloworld
|
|
./helloworld | fgrep 'Hello World'
|
|
'';
|
|
|
|
passthru.home = graalvmXXX-ee;
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = "https://www.graalvm.org/";
|
|
description = "High-Performance Polyglot VM";
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ volth hlolli ];
|
|
platforms = [ "x86_64-linux" ];
|
|
};
|
|
};
|
|
in
|
|
graalvmXXX-ee;
|
|
in {
|
|
graalvm8-ee = common "8";
|
|
graalvm11-ee = common "11";
|
|
}
|