From 33bbcacaf4e3d26d94cf2f306630c91aafca10b0 Mon Sep 17 00:00:00 2001
From: AndersonTorres <torres.anderson.85@protonmail.com>
Date: Thu, 14 Oct 2021 20:11:14 -0300
Subject: [PATCH] ciano: init at 0.2.4

---
 pkgs/applications/graphics/ciano/default.nix | 76 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  6 ++
 2 files changed, 82 insertions(+)
 create mode 100644 pkgs/applications/graphics/ciano/default.nix

diff --git a/pkgs/applications/graphics/ciano/default.nix b/pkgs/applications/graphics/ciano/default.nix
new file mode 100644
index 00000000000..dcaabed6b19
--- /dev/null
+++ b/pkgs/applications/graphics/ciano/default.nix
@@ -0,0 +1,76 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, desktop-file-utils
+, ffmpeg
+, gobject-introspection
+, granite
+, gtk
+, imagemagick
+, libgee
+, libhandy
+, libsecret
+, libsoup
+, meson
+, ninja
+, pkg-config
+, python
+, vala
+, wrapGAppsHook
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ciano";
+  version = "0.2.4";
+
+  src = fetchFromGitHub {
+    owner = "robertsanseries";
+    repo = pname;
+    rev = version;
+    hash = "sha256-nubm6vBWwsHrrmvFAL/cIzYPxg9B1EhnpC79IJMNuFY=";
+  };
+
+  nativeBuildInputs = [
+    desktop-file-utils
+    meson
+    ninja
+    pkg-config
+    python
+    vala
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    ffmpeg
+    imagemagick
+    granite
+    gtk
+  ];
+
+  postPatch = ''
+    chmod +x meson/post_install.py
+    patchShebangs meson/post_install.py
+  '';
+
+  dontWrapGApps = true;
+
+  postFixup = let
+    binPath = lib.makeBinPath [
+      ffmpeg
+      imagemagick
+    ];
+  in
+    ''
+      wrapProgram $out/bin/com.github.robertsanseries.ciano \
+         --prefix PATH : ${binPath} "''${gappsWrapperArgs[@]}"
+      ln -s $out/bin/com.github.robertsanseries.ciano $out/bin/ciano
+    '';
+
+  meta = with lib; {
+    homepage = "https://github.com/robertsanseries/ciano";
+    description = "A multimedia file converter focused on simplicity";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 0fb2cc738db..3d2bfe03539 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2150,6 +2150,12 @@ with pkgs;
 
   bs-platform = callPackage ../development/compilers/bs-platform {};
 
+  ciano = callPackage ../applications/graphics/ciano {
+    inherit (pantheon) granite;
+    python = python3;
+    gtk = gtk3;
+  };
+
   c3d = callPackage ../applications/graphics/c3d {
     inherit (darwin.apple_sdk.frameworks) Cocoa;
   };